Vulcan Nightmare

Experimentally bringing up vulcan support

assets/shaders/m2.frag.glsl

@@ -0,0 +1,86 @@
+#version 450
+
+layout(set = 0, binding = 0) uniform PerFrame {
+    mat4 view;
+    mat4 projection;
+    mat4 lightSpaceMatrix;
+    vec4 lightDir;
+    vec4 lightColor;
+    vec4 ambientColor;
+    vec4 viewPos;
+    vec4 fogColor;
+    vec4 fogParams;
+    vec4 shadowParams;
+};
+
+layout(set = 1, binding = 0) uniform sampler2D uTexture;
+
+layout(set = 1, binding = 2) uniform M2Material {
+    int hasTexture;
+    int alphaTest;
+    int colorKeyBlack;
+    float colorKeyThreshold;
+    int unlit;
+    int blendMode;
+    float fadeAlpha;
+    float interiorDarken;
+    float specularIntensity;
+};
+
+layout(set = 0, binding = 1) uniform sampler2DShadow uShadowMap;
+
+layout(location = 0) in vec3 FragPos;
+layout(location = 1) in vec3 Normal;
+layout(location = 2) in vec2 TexCoord;
+
+layout(location = 0) out vec4 outColor;
+
+void main() {
+    vec4 texColor = hasTexture != 0 ? texture(uTexture, TexCoord) : vec4(1.0);
+
+    if (alphaTest != 0 && texColor.a < 0.5) discard;
+    if (colorKeyBlack != 0) {
+        float lum = dot(texColor.rgb, vec3(0.299, 0.587, 0.114));
+        if (lum < colorKeyThreshold) discard;
+    }
+    if (blendMode == 1 && texColor.a < 0.004) discard;
+
+    vec3 norm = normalize(Normal);
+    if (!gl_FrontFacing) norm = -norm;
+
+    vec3 ldir = normalize(-lightDir.xyz);
+    float diff = max(dot(norm, ldir), 0.0);
+
+    vec3 result;
+    if (unlit != 0) {
+        result = texColor.rgb;
+    } else {
+        vec3 viewDir = normalize(viewPos.xyz - FragPos);
+        vec3 halfDir = normalize(ldir + viewDir);
+        float spec = pow(max(dot(norm, halfDir), 0.0), 32.0) * specularIntensity;
+
+        float shadow = 1.0;
+        if (shadowParams.x > 0.5) {
+            vec4 lsPos = lightSpaceMatrix * vec4(FragPos, 1.0);
+            vec3 proj = lsPos.xyz / lsPos.w * 0.5 + 0.5;
+            if (proj.z <= 1.0) {
+                float bias = max(0.005 * (1.0 - dot(norm, ldir)), 0.001);
+                shadow = texture(uShadowMap, vec3(proj.xy, proj.z - bias));
+            }
+            shadow = mix(1.0, shadow, shadowParams.y);
+        }
+
+        result = ambientColor.rgb * texColor.rgb
+               + shadow * (diff * lightColor.rgb * texColor.rgb + spec * lightColor.rgb);
+
+        if (interiorDarken > 0.0) {
+            result *= mix(1.0, 0.5, interiorDarken);
+        }
+    }
+
+    float dist = length(viewPos.xyz - FragPos);
+    float fogFactor = clamp((fogParams.y - dist) / (fogParams.y - fogParams.x), 0.0, 1.0);
+    result = mix(fogColor.rgb, result, fogFactor);
+
+    outColor = vec4(result, texColor.a * fadeAlpha);
+}